-- card: 3836 from stack: in
-- bmap block id: 3843
-- flags: 0000
-- background id: 2729
-- name: 


-- part 2 (button)
-- low flags: 00
-- high flags: 0000
-- rect: left=33 top=79 right=119 bottom=71
-- title width / last selected line: 0
-- icon id / first selected line: 19594 / 19594
-- text alignment: 1
-- font id: 20
-- text size: 10
-- style flags: 0
-- line height: 13
-- part name: Exbando
----- HyperTalk script -----
-- PostIt, the original version of this button was written
-- by Mark Igra, 1588 Henry St. #2.  Berkeley, CA 94709.
-- Copyright Mark Igra.
-- Hybrid, "Exbando" by Peter Martori, 605 W. Montebello, Phx, AZ 85013
--
-- This button creates a note that you can name, hide, move & delete.
-- The note consists of a text field and a button which hides
-- the field if it is visible and shows it if it is not.
-- You create the note by clicking this button, naming the note, then
-- clicking where you want the note to be located.
-- You can move the note by double-clicking and dragging the note to
-- where you want it (keep the mouse button down on the second click).
-- You can remove the note by option-clicking it (hold the optionKey
-- down, then click the note field).
--
-- Feel free to place this button or a variant on all stacks.  Please
-- include notice (first 4 lines).

global noteName
on mouseUp
  global noteName
  ask "Name the Note..."
  put it into noteName
  put the number of card fields + 1 into fieldNum
  put the userLevel into saveLevel
  set the userLevel to 5

  if the userLevel < 5 then
    answer "Can't make new fields now" with "OK"
    exit mouseUp
  end if

  -- You will probably want to take this notice out

  answer "Click where you want the note" with "Cancel" or "OK"
  if it is "Cancel" then exit mouseUp

  wait until the mouseClick
  wait until the mouseClick

  put the mouseLoc into noteLoc
  set the cursor to 4 -- watch
  set lockScreen to true

  -- Create the field

  choose field tool
  drag from noteLoc to item 1 of noteLoc + 150,item 2 of noteLoc + 200 with commandKey
  set the style of card field fieldNum to rectangle
  put the id of card field fieldNum into fieldID
  set the name of card field fieldNum to notename
  set the script of card field fieldNum to fieldscript
  -- Make the button

  makeButton noteLoc,fieldID

  -- Return everything to normal.

  choose browse tool
  set the userLevel to saveLevel
  set the cursor to saveCursor
  set lockScreen to false
end mouseUp

on makeButton noteLoc,fieldID
  global notename
  put the number of buttons + 1 into buttonNum
  choose button tool
  drag from noteLoc to item 1 of noteLoc + 150,item 2 of noteLoc + 15 with commandKey
  set the style of button buttonNum to rectangle
  set the textfont of button buttonNum to geneva
  set the textsize  of button buttonNum to 9
  set name of button buttonNum to notename
  set the showname of button buttonNum to true
  set the script of button buttonNum to PostItScript(fieldID)
end makeButton

-- The buttons that hide and show a post it note have a script
-- which is customized for the note they show.  The button's script
-- uses the id of the field so that it will work no matter how the
-- fields are shuffled.

function PostItScript fieldID
return "on mouseUp" & return¬  -- Note the use of 'return' as end of line
&& "Set the visible of card field id" && fieldID && "to not the visible of card field id" && fieldID & return & "end mouseUp"
end PostItScript




-- part 3 (field)
-- low flags: 80
-- high flags: 0002
-- rect: left=214 top=127 right=328 bottom=365
-- title width / last selected line: 0
-- icon id / first selected line: 0 / 0
-- text alignment: 0
-- font id: 20
-- text size: 14
-- style flags: 0
-- line height: 18
-- part name: Read all about it...
----- HyperTalk script -----
fieldscript


-- part 4 (button)
-- low flags: 00
-- high flags: 8002
-- rect: left=214 top=127 right=143 bottom=365
-- title width / last selected line: 0
-- icon id / first selected line: 0 / 0
-- text alignment: 1
-- font id: 3
-- text size: 9
-- style flags: 0
-- line height: 12
-- part name: Read all about it...
----- HyperTalk script -----
on mouseUp
  Set the visible of card field id 3 to not the visible of card field id 3
end mouseUp


-- part 5 (button)
-- low flags: 00
-- high flags: 8003
-- rect: left=397 top=190 right=212 bottom=480
-- title width / last selected line: 0
-- icon id / first selected line: 0 / 0
-- text alignment: 1
-- font id: 20
-- text size: 10
-- style flags: 0
-- line height: 13
-- part name: Pixie!
----- HyperTalk script -----
-----------------------------------------------
--  this mahvelous tool is by  Leigh Lundin  --
--  Independent  Intelligence  Incorporated  --
--  Orlando, Florida  32854    407-644-1011  --
--  GEnie: Leigh.Lundin     CIS: 76367,1277  --
--  (The Macintosh User's Group of Orlando)  --
--  © 1988 Leigh Lundin All rights reserved  --
-----------------------------------------------

--Pixie! 1.0.0   A pixel locater.   • IT'S FREE! •

--Pixie! is released for general use with the proviso that this
--notice remain in place, that modifications be reported to the
--author, and credit for its use be noted in your applications.

--Want accurate coordinates for your art work and buttons?
--Been wondering how to identify locations for your scripts?
--(a) Click to activate the button and click again to note the location.
--(b) To relocate the button, click and drag it to a convenient place.
--(c) If this button resides in your Home stack, the button copies
--    itself to the Clipboard so you can Paste it in another stack.

--Pixies live!
--  Leigh Lundin  15 March 1988

on mouseDown
  set hilight of the target to true
  if the short name of this stack = "Home"
  then
  set lockScreen to true
  put the userLevel into origUserLevel
  if origUserLevel < 4 then set userLevel to 4
  choose "button tool"
  click at the loc of the target
  doMenu "Copy button"
  choose "browse tool"
  set userLevel to origUserLevel
  set lockScreen to false
else wait 10 ticks   -- adjust value for activation lag
if the mouse is down
then
set cursor to 3
set the name of the target to "Wheee!"
repeat until the mouse is up
  set hilight of the target to false
  set the loc of the target to the mouseLoc
  set hilight of the target to true
  set the loc of the target to the mouseLoc
end repeat
set the name of the target to "Pixie!"
else
  set cursor to 2
  repeat until the mouseClick
    set the name of the target to "Pixie! "&the mouseLoc
  end repeat
  set the name of the target to "Pixie! "&the mouseLoc -- 1 last time!
end if
set hilight of the target to false
end mouseDown




-- part contents for background part 1
----- text -----
I fooled around with Mark's creation and came up with just the thing.  Or so I thought.  It performed as advertised but had a few problems.  It was hard to get rid of when no longer needed and was obscured by notes left open 
that were "closer".

This little project became a means for me to learn something about HyperTalk.  I set to work on finding a way to move the dumb notes around.

A great little button called "Pixie" gave me the clue.
Leigh Lundin  of Independent  Intelligence has put this diminutive powerhouse out into the world for free.  One of the neatest things about it is a feature that allows you to move it around a card by just holding down the mouse button.  When you do it blinks and says "Wheee!"

-- part contents for card part 3
----- text -----

This note kind of gets in the way if you leave it open.

If I always closed my notes and put my socks in the hamper I probably wouldn't be messing around with this stuff.